home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 17 / CU Amiga Magazine's Super CD-ROM 17 (1997)(EMAP Images)(GB)[!][issue 1997-12].iso / InitCD < prev    next >
AmigaDOS Script File  |  1997-09-19  |  5KB  |  160 lines
  1. .key arg
  2. .bra {
  3. .ket }
  4.  
  5. ; CUCD Init Script
  6. ;
  7. ; Set up assigns etc. both for users booting from the CD and from  HD
  8. ;
  9. ; Version 1.1 - Changed jpegtmp
  10. ;
  11. ; Version 1.2 - Added uninit option
  12. ;
  13. ; Version 1.3 - Added CHECK argument and link to Prefs editor
  14.  
  15. Assign CUCD: :
  16.  
  17. ; Make some commands resident to speed up things on CD32s in particular
  18. Resident >NIL: CUCD:C/RequestChoice PURE
  19. Resident >NIL: CUCD:rexxc/rx PURE
  20. Resident >NIL: CUCD:C/Version PURE
  21.  
  22. If {arg} EQ "CHECK"         ; Exit if InitCD has been run, otherwise ask
  23.     If $CDInit EQ TRUE
  24.         Skip END
  25.     Else
  26.         set init `CUCD:C/RequestChoice "CU Amiga CD" "InitCD needs to be run first*NWould you like to run it now?" "Yes|No"`
  27.         If $init EQ 0
  28.             Skip END
  29.             EndIf
  30.         EndIf
  31.     EndIf
  32.  
  33. If $CDInit EQ TRUE
  34.     If $CDBoot EQ TRUE          ; don't run UninitCD if booted from CD
  35.         CUCD:C/RequestChoice >NIL: "CU Amiga CD" "You do not need to run InitCD*Nwhen you have booted from the CD" "OK" 
  36.         Skip END
  37.         EndIf
  38.     set remass `CUCD:C/RequestChoice "InitCD" "You have already run InitCD once.*NDo you wish to remove the assigns and paths added before?" "Remove|Cancel"`
  39.     If $remass EQ 1
  40.         execute UnInitCD
  41.         EndIf
  42.     Skip END
  43.     EndIf
  44.  
  45. ; Set some system assigns
  46. Assign WWW:             CUCD:CUCD/WWW
  47. Assign tcpdldir:        CUCD:CUCD/WWW
  48. Assign GM:              CUCD:CDsupport/GMPlay ADD
  49. Assign CUCDNews:        CUCD:CUCD/Online/News
  50. Assign Twist:           CUCD:CUCD/Magazine/Issues
  51. Assign TwistIcon:       Twist:Icons
  52.  
  53. ; Add paths
  54. Path GM: ADD
  55.  
  56. ; Add MUI if no MUI installed.
  57. Assign MUI: EXISTS >NIL:
  58. IF WARN
  59.     Assign MUI:    CUCD:CDsupport/MUI
  60.     Assign Libs:   MUI:Libs ADD
  61.     Assign LOCALE: MUI:Locale ADD
  62.     Assign HELP: exists >NIL:
  63.     If NOT WARN
  64.         Dir >NIL: HELP:
  65.         EndIf
  66.     Assign HELP:   MUI:Docs ADD
  67. Else
  68.     :C/UpdateCopy >NIL: CUCD:CDsupport/MUI/Libs/MUI/Icon.mcc MUI:Libs/MUI CLONE DEEP
  69.     EndIf
  70.  
  71. ; Set assigns and paths for programs on this CD
  72. Execute CUCD:S/ThisCD
  73.  
  74. ;BEGIN ClassAct
  75. CUCD:C/CAPrefs >NIL:
  76. ;END ClassAct
  77.  
  78. ; start arexx if not running
  79. CUCD:rexxc/rx "address command" >NIL:
  80. If WARN
  81.     CUCD:System/RexxMast >NIL:
  82.     EndIf
  83.  
  84. IF $CDBoot EQ TRUE
  85.     Run <NIL: >NIL: CUCD:C/NewIcons
  86.     CUCD:C/DefIcons
  87. Else
  88.     ; All this is only needed when not booting from the CD
  89.     Run >NIL: RequestChoice "InitCD" "Setting up some assigns and paths to run software from the CD.*NIf you wish to remove the CD from the drive, run InitCD again,*Notherwise the icon will stay on the Workbench." " OK "
  90.     Assign Fonts:   CUCD:Fonts ADD
  91.     Assign Libs:    CUCD:Libs ADD
  92.     Assign L:       CUCD:L ADD
  93.     Assign S:       CUCD:S ADD
  94.     Assign LIBS:    CUCD:Classes ADD
  95.     Path CUCD:C CUCD:CDsupport CUCD:System CUCD:Utilities CUCD:S CUCD:Rexxc ADD
  96.  
  97.     ; Make environment variables defined on CD available to system
  98.     Failat 21
  99.     Assign >NIL: ENV: CUCD:Prefs/Env-Archive ADD
  100.     ; For HappyENV users
  101.     If FAIL     
  102.         Assign >NIL: ENVARC: CUCD:Prefs/Env-Archive ADD
  103.         EndIf
  104.  
  105.     ;Start NewIcons if not already running
  106.     If $NoNewIcons NOT EQ TRUE
  107.         CUCD:C/isnirunning
  108.         If NOT WARN
  109.             Run <NIL: >NIL: CUCD:C/NewIcons
  110.             CUCD:C/DefIcons
  111.             EndIf
  112.         EndIf
  113.  
  114.     ; Update workbench paths unless running Directory Opus 5.11 or 5.5 in WBR mode
  115.     Version >NIL: C:LoadWB 43
  116.     If WARN
  117.        C:LoadWB NEWPATH
  118.     Else
  119.         Version >NIL: C:LoadWB 60
  120.         If NOT WARN
  121.             C:LoadWB NEWPATH
  122.             EndIf
  123.         EndIf
  124.  
  125.     ; Check that libraries on boot drive are up to date
  126.     ;Execute CUCD:S/UpdateLibrary rexxdossupport.library 3 5
  127.     ;Execute CUCD:S/UpdateLibrary rexxreqtools.library  37 95
  128.     ;Execute CUCD:S/UpdateLibrary newicon.library 39 1
  129.     ;Execute CUCD:S/UpdateLibrary cando.library 3 8
  130.  
  131.     ; Give option for setting CD preferences
  132.     Version >NIL: version 37
  133.     If NOT WARN
  134.         If NOT EXISTS ENV:IDer.prefs
  135.             set edit `RequestChoice "CU Amiga CD" "CUCD now has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
  136.             If $edit EQ 1
  137.                 cd CUCD:S
  138.                 :RexxC/MuiRexx CUCDPrefs.mrx port CDPREFS
  139.             else
  140.                 RequestChoice >NIL: "CU Amiga CD" "You can run CUCD preferences at any time.*NIt is in the Prefs drawer of the CD" "OK"
  141.                 EndIf
  142.             EndIf
  143.     Else
  144.         If NOT EXISTS ENV:IDer.prefs
  145.             Copy >NIL: CUCD:S/IDer.prefs_OS2 ENV:IDer.prefs
  146.             EndIf
  147.         EndIf
  148.  
  149.     EndIf
  150.  
  151. SetEnv CDInit TRUE
  152.  
  153. LAB END
  154.  
  155. ; Remove commands made resident earlier
  156. Resident >NIL: RequestChoice REMOVE
  157. Resident >NIL: rx REMOVE
  158. Resident >NIL: Version REMOVE
  159.  
  160.